Partial derivatives

f[x_,y_]:=x^2Sin[2y]/32

surface=Plot3D[f[x,y],{x,0,100},{y,0,1.57},PlotStyle->Opacity[.2],AxesLabel->{Style["x",20,Bold],Style["y",20,Bold],Style["z",20,Bold]},AxesStyle->14]

Trace with x = 75 fixed

Show[surface,ParametricPlot3D[{75,y,f[75,y]},{y,0,1.57},PlotStyle->{Blue, Thick}]]

Plot[f[75,y],{y,0,1.57},PlotRange-> All]

Trace with y = 0.5 fixed

Show[surface,ParametricPlot3D[{x,.5,f[x,.5]},{x,0,100},PlotStyle->{Purple, Thick}]]

Plot[f[x,.5],{x,0,100},PlotRange-> All]

Partial derivatives give the slope of the traces (change one variable, hold other fixed), and can be used to find the tangent lines

D[f[x,y],x]

fx[x_,y_]:=(1/16) x Sin[2 y]

D[f[x,y],y]

fy[x_,y_]:=(1/16) (x^2) Cos[2 y]

Show[surface,ParametricPlot3D[{75,y,f[75,y]},{y,0,1.57},PlotStyle->{Blue, Thick}],ParametricPlot3D[{x,.5,f[x,.5]},{x,0,100},PlotStyle->{Purple, Thick}],ParametricPlot3D[{75,t+.5,fy[75,.5]t+f[75,.5]},{t,-1/2,1/2},PlotStyle->{Black, Thick}],ParametricPlot3D[{t+75,.5,fx[75,.5]t+f[75,.5]},{t,-100,100},PlotStyle->{Black, Thick}]]

Second partial derivatives

(Subscript[f, xx]) tells us how the slope in the x-direction is changing with x

Manipulate[Show[surface,ParametricPlot3D[{x,.5,f[x,.5]},{x,0,100},PlotStyle->{Purple, Thick}],ParametricPlot3D[{t+x0,.5,fx[x0,.5]t+f[x0,.5]},{t,-100,100},PlotStyle->{Black, Thick}]],{x0,10,90}]

D[f[x,y],x,x]/.{x->75,y->.5}

(Subscript[f, yy]) tells us how the slope in the y-direction is changing with y

Manipulate[Show[surface,ParametricPlot3D[{75,y,f[75,y]},{y,0,1.57},PlotStyle->{Blue, Thick}],ParametricPlot3D[{75,t+y0,fy[75,y0]t+f[75,y0]},{t,-1/2,1/2},PlotStyle->{Black, Thick}]],{y0,.1,1.4}]

D[f[x,y],y,y]/.{x->75,y->.5}

(Subscript[f, xy]) tells us how the slope in the x-direction is changing with y

Manipulate[Show[surface,ParametricPlot3D[{x,y0,f[x,y0]},{x,0,100},PlotStyle->{Purple, Thick}],ParametricPlot3D[{t+75,y0,fx[75,y0]t+f[75,y0]},{t,-100,100},PlotStyle->{Black, Thick}]],{y0,.1,1.4}]

D[f[x,y],x,y]/.{x->75,y->.5}

(Subscript[f, yx]) tells us how the slope in the y-direction is changing with x

Manipulate[Show[surface,ParametricPlot3D[{x0,y,f[x0,y]},{y,0,1.57},PlotStyle->{Blue, Thick}],ParametricPlot3D[{x0,t+.5,fy[x0,.5]t+f[x0,.5]},{t,-1/2,1/2},PlotStyle->{Black, Thick}]],{x0,10,90}]

D[f[x,y],y,x]/.{x->75,y->.5}