f[x_,y_,a_]:=a-x-4 x y/(1+x^2)
g[x_,y_,b_]:=b x(1-y/(1+x^2))

fixedpt=Flatten[Solve[{f[x,y,a]==0,g[x,y,b]==0},{x,y}]]

A=Simplify[{{D[f[x,y,a],x],D[f[x,y,a],y]},{D[g[x,y,b],x],D[g[x,y,b],y]}}/.fixedpt]

Simplify[Eigenvalues[A]]

Want to know whether square root expression is greater than part out front:

Simplify[(15625+9 (a^4)-1250 a b-130 (a^3) b+25 (a^2) (-30+(b^2)))-(125-3 (a^2)+5 a b)^2]

We see the expression under the square root is (125-3 (a^2)+5 a b)^2 plus something negative, so square root expression is either real and smaller than the part out front(125-3 (a^2)+5 a b), or imaginary.

So the fixed point is an attractor if (125-3 (a^2)+5 a b)>0 and a repellor if (125-3 (a^2)+5 a b)<0.

Assuming[a>0 &&  b>0,Simplify[Solve[125-3 (a^2)+5 a b==0,b]]]

Hence the fixed point is an attractor if b>-(25/a)+((3 a)/5) (region to left) and a repellor if b<-(25/a)+((3 a)/5) (region to right).

Plot[3a/5-25/a,{a,6,20},PlotRange->{{0,20},{0,10}},AxesLabel->{a,b}]

Experiment: Set T to max, b to 6, alter a to cross bifurcation threshold.
(May be slow to graph curve--wait a second.)

Manipulate[sol=NDSolve[{x'[t]==f[x[t],y[t],a],y'[t]==g[x[t],y[t],b],x[0]==x0,y[0]==y0},{x[t],y[t]},{t,0,T}];
Show[ParametricPlot[{x[t],y[t]}/.sol,{t,0,T}],Graphics[Disk[{x0,y0},.1]],Graphics[{Blue,Disk[{(a/5),(1/25) (25+(a^2))},.1]}],AxesOrigin->{0,0},PlotRange->All,PlotLabel->"Fixed point marked in blue, initial condition in black."],{x0,1,5},{y0,1,12},{a,0.1,20},{b,0.1,10},{T,1,30}]

Period estimate for limit cycle: examine imaginary part of eigenvalue (from the square root expression) at the bifurcation threshold b=-(25/a)+((3 a)/5):

omega=Sqrt[Simplify[-((15625+9 (a^4)-1250 a b-130 (a^3) b+25 (a^2) (-30+(b^2)))/((2 (25+(a^2)))^2))/.{b->3a/5-25/a}]]

PeriodEstimate=2 Pi/omega

Limit[PeriodEstimate,a->Infinity]

N[((2 π)/(Sqrt[15]))]